PAL16L8
JLB/CJTC 11AUG86
45001B, 8D, BPAR

/BDRY50 /BDRY75 /BLOCK25 /BPERR50 DBAPR /MOR25 /LPERR /MR /EPES GND
/EPEA SPES /LERR TEST NC15 /RERR /PARERR /BLOCK SPEA VCC

; STROBE PARITY ERROR STATUS WORD

IF (/TEST) /SPES = /BDRY50 * /BDRY75
                 + BDRY50 * BDRY75
                 + /BDRY50 * BDRY75
                 + BLOCK25
                 + EPEA
                 + EPES
                 + MR

; STROBE PARITY ERROR ADDRESS

IF (/TEST) /SPEA = /DBAPR 
                 + BLOCK25 
                 + EPEA 
                 + MR

; BLOCK SIGNAL FOR PES AND PEA STROBE - BLOCK ON ERROR, RELEASE ON PEA READ

IF (/TEST) BLOCK = BDRY50 * /BDRY75 * /EPEA * /EPES * MOR25   * /MR
                 + BDRY50 * /BDRY75 * /EPEA * /EPES * BPERR50 * /MR
                 + BLOCK * /EPEA                              * /MR

; PARITY ERROR SIGNALS FROM BUS AND LOCAL MEMORY

IF (/TEST) PARERR = BDRY50 * /BDRY75 * BPERR50 * /MR
                  + LERR

; REMOTE ERROR - LAST ERROR WAS FROM MEMORY ATTACHED TO THE ND100 BUS
; WILL BE OVERRIDEN BY AN ERROR FROM LOCAL MEMORY (PERR1 AND PERR0)

IF (/TEST) RERR = BPERR50 * /MR ;SET REMOTE ERROR ON BUS PARITY E
               + RERR * /LPERR * /MR ;HOLD UNTIL A LOCAL MEMORY ERROR
               + MOR25 * /MR ;=> LOCAL ERROR HAS PRIORITY

DESCRIPTION

; 260387 CJTC: NEED TO USE DELAYED BAPR (DBAPR) INSTEAD OF /BAPR IN
;       PRODUCING SPEA. POLARITY CHANGE.

; 260387 JLB: BLOCK SIGNAL MUST NOT BE PRODUCED ON LOCAL MEMORY ERROR.
; IT WILL ONLY BE UNLOCKED ON PEA READ FROM REMOTE ERROR PEA.
; 260387 JLB: PERR HANDLING CHANGED.
; 070487 JLB: RERR MUST LATCH UP ON MOR ALSO.

; 180587 M3202B
; 090887 B JLB: TEST MODE FOR C-PRINT.